[IoT] ESP32 - 이미지 FTP 서버에 업로드 하기

지난번 글에서 작성했던 것 처럼, ESP32-Cam 라이브러리에 예제로 얼굴 검출, 인식, 등록하는 기능이 제공된다. 하지만, 졸업작품 주제는 "마스크 유무와 체온을 확인할 수 있는 무인 출입 관리 시스템" 이었기 때문에, 마스크 착용 유무를 검출하는 것이 중요한 태스크였다.

 

ESP32 에서 제공되는 예제로는 마스크를 착용한 얼굴을 인식할 수 없었기 때문에, 외부 라이브러리를 활용했다. 마스크 착용 유무를 판단하기 위해 머신러닝을 이용하므로 Ubuntu 서버로 이미지를 전송하는 것부터 시작해야했다.

 

ESP32 에서 FTP 서버에 데이터를 전송하기 위해서는 ESP32_FTPClient 라이브러리를 사용했다. FTP 서버에 디렉토리 생성하기, 파일 쓰기, 이미지 쓰기 기능들을 사용할 수 있고, 예제파일로 제공된다.

ldab/ESP32_FTPClient

ESP32-Cam 을 이용해서 사진을 촬영하고 FTP 서버에 업로드 하는 코드는 다음과 같다.

• FTPClient 와 관련된 변수와 함수들만 남겨둔 것이라 사용할 때에는 적절하게 추가해주셔야 합니다!

• 현재 사진이 촬영된 시간으로 이름을 지정하기 위해서 NTPClient 라이브러리를 이용했다. 

ESP32_FTPClient 클래스의 instance 인 ftp 를 생성한다.

• FTP server 의 ip 혹은 domain 주소, server 의 user id, password 를 인자로 넘긴다.

• setup 함수 내에서 Wifi, 카메라 세팅을 진행한 후 beginFTP 함수를 통해 FTP 전송을 시작했다.

• loop 함수가 아닌 setup 함수 내에서 실행한 이유는 모션 센서로 인한 부팅을 설정해두었고, 부팅 이후 동작들을 수행한 후 다시 DeepSleep 모드로 진입하기 위해서이다. (코드 내에서는 생략되어 있다.)

이미지를 전송하기 위한 beginFTP 함수

• 먼저 ftp.OpenConnection() 함수를 통해 연결을 시도한다. 

• 현재 시간을 얻기 위해 getDateTime() 함수를 호출하고, 이미지 파일명을 지정한다. 

  • 해당 함수의 반환 값은 2020_10_4_14:55:55 같은 형태가 되도록 작성했다.

• 카메라로부터 사진을 촬영하고, FTP 서버에 업로드한다.

  • esp_camera_fb_get() 함수를 통해 캡쳐된 이미지를 얻을 수 있다.

  • FTPClient 라이브러리에서 Type I 는 이미지 파일을 의미한다.

• ftp.CloseConnection() 함수를 통해 연결을 종료한다.

#include <ESP32_FTPClient.h>
#include <NTPClient.h>
#include <WiFiUdp.h>

/* FTP server settings */
char ftp_server[] = "ip";
char ftp_user[]   = "id";
char ftp_pass[]   = "pw";
ESP32_FTPClient ftp (ftp_server,ftp_user,ftp_pass, 5000, 2);

/* Define NTP Client to get time */
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "kr.pool.ntp.org");

void setup() { 
    /* Boot :: put your setup code here, to run once: */
    Serial.begin(115200);
    beginWiFi();
    configCamera();
    beginFTP();
}

String getDateTime() {
    timeClient.begin();
    timeClient.setTimeOffset(32400); // GMT+9
    timeClient.update();

    // Get a time structure
    unsigned long epochTime = timeClient.getEpochTime();
    struct tm *ptm = gmtime ((time_t *)&epochTime);

    int monthDay = ptm->tm_mday;
    int currentMonth = ptm->tm_mon+1;
    int currentYear = ptm->tm_year+1900;
    String currentDate = String(currentYear) + "_" + String(currentMonth) + "_" + String(monthDay);
    String formattedTime = timeClient.getFormattedTime();

    // Print complete date: 2020_10_4_14:55:55
    String currentDateTime = currentDate + "_" + formattedTime;
    //Serial.print("Current date time: "); Serial.println(currentDateTime);
    return currentDateTime;
}

void beginFTP(){  
    camera_fb_t * fb = NULL;
    ftp.OpenConnection();

    // Image file name
    String currentDateTime = getDateTime();
    String tem_name = "cam_" + currentDateTime + ".jpg";
    const char *fname = tem_name.c_str();

    // Upload image
    fb = esp_camera_fb_get();  
    ftp.InitFile("Type I");
    ftp.NewFile(fname);
    ftp.WriteData(fb->buf, fb->len);
    ftp.CloseFile();
    Serial.print("uploaded:"); 
    Serial.println(tem_name);

    ftp.CloseConnection();
    esp_camera_fb_return(fb);
}

void loop() {}

 

위의 코드를 작성한 이미지가 없어서 예제를 돌리면 다음과 같이 파일 업로드가 진행된다. TMP006 이라는 온도센서 측정과 함께 FTP 이미지 업로드를 실행한 경우이다. 

---

참고한 사이트

• zerowincoding.tistory.com/entry/ESP32-CAM-스틸사진-캡쳐-FTP-업로드
• github.com/ldab/ESP32_FTPClient